Configuration Arduino pour une connexion GPRS avec une SIM EMnify

/*
  Simple HTTP Client over GPRS
 
Cette configuration établie une connection GPRS et envoie une requête HTTP à un URL codé. 
 
 Circuit:
 * Arduino avec un emplacement SIM pour GSM
 * Une carte SIM EMnify inséré dans l'appareil
 
 */

// Include GSM library
#include <GSM.h>

// Le code PIN est désactivé pour les cartes SIM EMnify par défaut
#define PIN ""

// configuration APN
#define GPRS_APN       "em" // Nom de l'APN EMnify 
#define GPRS_USERNAME  ""   // laisser vide pour la SIM EMnify 
#define GPRS_PASSWORD  ""   // laisser vide pour la SIM EMnify

// Hôte, port et chemin de l'URL pour se connecter à 
char host[] = "www.emnify.com";
int port = 80; // port 80  for HTTP
char path[] = "/arduino.html";

// Initialiser la librairie
GSMClient client;
GPRS gprs;
GSM gsmAccess; 

void setup()
{
  // initialize serial communications
  Serial.begin(9600);

  // GSM connection state
  boolean gsmConnected = false;

  Serial.println("Trying to attach to GPRS network...");

  while(!gsmConnected)
  {
    if (gsmAccess.begin(PIN) == GSM_READY)  
    {
      if(gprs.attachGPRS(GPRS_APN, GPRS_USERNAME, GPRS_PASSWORD) == GPRS_READY)
      {
        gsmConnected = true;
        Serial.println("Connected to GPRS network successfully");
      }
    else
      {
        Serial.println("GPRS not connected, retrying after 3 seconds...");
        delay(3000);
      }
    }
  }
}

int http_request()
{
  Serial.print("Connecting to ");
  Serial.print(host);
  Serial.print(":");
  Serial.println(port);

  // establish TCP connection
  if (client.connect(host, port))
  {
    Serial.println("Connected");    
    // Send HTTP request and request to close connection
    client.print("GET ");
    client.print(path);
    client.println(" HTTP/1.1");
    client.print("Host: ");
    client.println(host);
    client.println("Connection: close");
    client.println();
  } 
  else
  {
    // report connection failure
    Serial.println("connection failed");
    return(0);
  }

  // read and print incoming data or stop connection if we are disconnected

  for (;;)
  {
    if (client.available())
    {
      char c = client.read();
      Serial.print(c);
    }

    // if the server's disconnected, stop the client:
    if (!client.available() && !client.connected())
    {
      Serial.println();
      Serial.println("Disconnecting.");
      client.stop();

      return(1);  
    }
  }
}

void loop()
{
  int counter = 0;

  // repeat request every 60 seconds and count number of requests
  Serial.print("Trying to make http request number ");
  Serial.println(counter++);

  http_request();

  Serial.println("Sleeping 60 secs before next request");
  delay(60000);
}